Capítulo 1. Curso de introducción

Parte 6: Empecemos a trabajar

Contenido:

A estas alturas ya sabemos qué podemos y qué no podemos hacer con el ordenador, así como la forma de conectarle periféricos. Sabemos para qué sirven algunas teclas del ordenador y cómo cargar programas. Ahora vamos a ver algunas de la órdenes e instrucciones que usted puede teclear para que empiecen a ocurrir cosas.

Al ordenador le ocurre lo que a los humanos: sólo puede entender instrucciones que se le dan en el lenguaje que él conoce. En el caso del ordenador, ese lenguaje es BASIC (siglas de Beginners' All-purpose Symbolic Instruction Code, "código de instrucciones simbólicas de uso general para principiantes"). Las palabras del vocabulario de BASIC son la llamadas "palabras clave", "palabras reservadas" o "palabras de instrucción". Cada una de ellas ordena a la máquina que realice una determinada función. Todos los lenguajes tienen sus reglas gramaticales, y BASIC no es la excepción. Aquí, el concepto de gramática se reduce al de "sintaxis"; de ahí que el ordenador tenga la amabilidad de decirnos de vez en cuando que hemos cometido un error de sintaxis: Syntax error.

Introducción a las palabras clave del BASIC de AMSTRAD

En el tercer capítulo, titulado "Lista completa de las palabras clave del BASIC de AMSTRAD", daremos una descripción de todas las palabras del dialecto de BASIC que entiende este ordenador. En esta sección vamos a presentar sólo las que se utilizan con mayor frecuencia.

CLS

Para borrar la pantalla escriba: 

cls [RETURN]

Como puede observar, la pantalla efectivamente se borra y en su extremo superior izquierdo aparecen la palabra Ready y el cursor ∎.

Para introducir palabras clave de BASIC valen tanto las letras mayúsculas como las minúsculas.

PRINT

Esta instrucción sirve para hacer que el ordenador escriba en la pantalla caracteres sueltos, palabras completas, frases o números. Teclee la siguiente orden: 

print "hola" [RETURN]

En la pantalla puede ver: 

hola

Las comillas "" indican al ordenador qué es lo que debe escribir. La palabra hola apareció en la pantalla en cuanto se pulsó [RETURN]. Teclee 

cls [RETURN]

para borrar la pantalla.

RUN

En el ejemplo anterior hemos visto cómo obedece el ordenador una orden directa. Pero esto no siempre es deseable, ya que el ordenador olvida la orden inmediatamente después de ejecutarla. Podemos almacenar en la memoria del ordenador una sucesión de instrucciones para que más tarde sean ejecutadas en un orden determinado. Tal sucesión de instrucciones constituirá un programa. Las instrucciones de BASIC que podemos incluir en un programa tienen la forma que hemos visto, pero van precedidas de un número de línea. Si el programa consta de más de una instrucción, los números de línea indican al ordenador en qué orden debe ejecutarlas. Cuando después de teclear una línea de instrucción se pulsa [RETURN], la línea queda almacenada en la memoria hasta que pidamos al ordenador que ejecute el programa. Escriba lo siguiente: 

10 print "hola" [RETURN]

Observe que en este caso, aunque ha pulsado [RETURN], la palabra hola no ha aparecido en la pantalla, sino que ha quedado almacenada en la memoria del ordenador, incluida en la línea de programa. Para ejecutar este pequeño programa debemos dar al ordenador la orden directa run. Escriba 

run [RETURN]

Ahora sí aparece la palabra hola en la pantalla.

Observe algo interesante: en lugar de escribir la palabra print completa, basta con teclear el signo de interrogación ?; por ejemplo, 

10 ? "hola" [RETURN]

LIST

Cuando se tiene un programa almacenado en la memoria, se puede comprobar su contenido haciendo un "listado". Escriba 

list [RETURN]

En la pantalla aparece 

10 PRINT "hola"

que es la única línea de nuestro programa.

Observe que ahora la palabra PRINT está en mayúsculas. Esto nos indica que el ordenador ha reconocido PRINT como palabra clave de BASIC.

Escriba cls [RETURN] para borrar la pantalla. Observe que, aunque se ha borrado el texto que había en la pantalla, el programa sigue estando en la memoria del ordenador.

GOTO

Esta instrucción pide al ordenador que salte de la línea actual a la línea especificada, para no ejecutar un grupo de instrucciones, si el salto es hacia delante, o para formar un bucle, si el salto es hacia atrás. Escriba 

10 print "hola" [RETURN]
20 goto 10 [RETURN]

y luego 

run [RETURN]

Como puede ver, el ordenador escribe repetidamente la palabra hola, a la izquierda de la pantalla, pasando cada vez a la línea siguiente. La razón es que, al llegar a la línea 20, la instrucción goto 10 provoca un salto a la línea 10.

Para detener el programa, pulse [ESC] una vez. Para reanudarlo, pulse cualquier otra tecla. Para detenerlo definitivamente, de forma que se pueda introducir otras instrucciones, pulse [ESC] dos veces.

Escriba ahora 

cls [RETURN]

para borrar la pantalla.

Para inhibir el salto a la línea siguiente de la pantalla cada vez que el ordenador escriba hola, introduzca nuevamente el programa anterior, pero poniendo ahora un signo de punto y coma (;) al final de las comillas: 

10 print "hola"; [RETURN]
20 goto 10 [RETURN]
run [RETURN]

El punto y coma indica al ordenador que debe escribir el siguiente grupo de caracteres inmediatamente a la derecha del anterior (suponiendo que quepan en la misma línea).

Para detener este programa pulse [ESC] dos veces. Escriba otra vez la línea 10, pero poniendo una coma (,) en lugar del punto y coma (,): 

10 print "hola", [RETURN]
run [RETURN]

Como puede observar, la coma ha indicado al ordenador que escriba el siguiente grupo de caracteres 13 posiciones a la derecha del lugar en que empezó a escribir el anterior. Esta función es útil cuando se quiere visualizar información en columnas. No obstante, si el número de caracteres del grupo es mayor que 12, la escritura empezará otras 13 posiciones más a la derecha, de forma que entre columnas siempre quedará algún espacio.

Este número, 13, es modificable con la instrucción ZONE, que describiremos más adelante.

Para detener este programa, pulse [ESC] dos veces. Para borrar completamente la memoria del ordenador, pulse las teclas [CONTROL] y [MAYS] y, antes de soltarlas, pulse [ESC].

INPUT

Esta instrucción hace que el ordenador quede a la espera de que el usuario introduzca información por el teclado; por ejemplo, en respuesta a alguna pregunta.

Escriba lo siguiente: 

10 input "cuantos años tienes";edad [RETURN]
20 print "pues no aparentas tener";edad;"años" [RETURN]
run [RETURN]

En la pantalla aparece la pregunta: 

cuantos años tienes?

Escriba su edad y pulse [RETURN]. Si, por ejemplo, su edad es 18 años, el programa escribe lo siguiente: 

pues no aparentas tener 18 años

Este ejemplo ilustra la utilización de input combinada con una variable numérica. Hemos puesto la palabra edad al final de la línea 10, y por consiguiente en la memoria, para que el ordenador pueda asociarla al número que el usuario introduzca; después, en la línea 20, en lugar de edad escribirá ese número. Nada nos obligaba a elegir precisamente ese nombre, edad, y podíamos haber utilizado una letra cualquiera, por ejemplo, b.

Reinicialice el ordenador para borrar la memoria (teclas [CONTROL] [MAYS] [ESC]. Si queremos captar por el teclado una respuesta que esté formada por caracteres cualesquiera (letras so las o letras mezcladas con números), debemos poner el signo de dólar ($) al final del nombre de la variable. Las variables de este tipo son las que denominamos variables literales.

Escriba el siguiente programa (observe que en la línea 20 hay que poner un espacio después de la primera coma, pero no antes de la segunda): 

10 input "como te llamas";nombre$ [RETURN]
20 print "hola, ";nombre$;", yo me llamo Rolando" [RETURN]
run [RETURN]

En la pantalla puede ver: 

como te llamas?

Escriba su nombre y luego pulse [RETURN]. Si el nombre introducido es, por ejemplo, Manolo, el programa escribe: 

hola, Manolo, yo me llamo Rolando

En este caso hemos usado nombre$ como nombre de la variable literal, pero perfectamente podríamos haber elegido una letra cualquiera, por ejemplo, a$. Vamos a combinar los dos ejemplos anteriores en un solo programa.

Reinicialice la máquina con [CONTROL] [MAYS] [ESC]. Escriba lo siguiente: 

5 cls [RETURN]
10 input "como te llamas";a$ [RETURN]
20 input "cuantos años tienes";b [RETURN]
30 print "desde luego, ";a$;", no aparentas tener";b;"años" [RETURN]
run [RETURN]

En este programa hemos utilizado dos variables: a$ para representar el nombre y b para representar la edad. En la pantalla aparece la primera pregunta: 

como te llamas?

Escriba su nombre (supongamos que es Manolo) y luego pulse [RETURN]. El ordenador le pregunta ahora: 

cuantos años tienes?

Escriba su edad (supongamos que es 18 años) y luego pulse [RETURN].

Si lo que hemos supuesto es cierto, en la pantalla aparecerá la siguiente frase:

desde luego, Manolo, no aparentas tener 18 años

Edición de programas

Si alguna de las líneas del programa anterior hubiera sido mecanografiada incorrectamente, lo que podría provocar el mensaje de error Syntax error o algún otro, en lugar de escribirla de nuevo es posible corregirla ("editarla" es como se dice en informática). Para ilustrar cómo hacerlo, vamos a escribir incorrectamente el programa: 

5 clss [RETURN]
10 input "como t llamas";a$ [RETURN]
20 input "cuantos años tienes";b [RETURN]
30 print "desde luego,";a$;", no aparentas tener";b;"años" [RETURN]

En este programa hay tres errores:

  1. En la línea 5 hemos escrito clss en lugar de cls.
  2. En la línea 10 hemos escrito t en lugar de te.
  3. En la línea 30 hemos olvidado poner un espacio entre la coma y el signo de cerrar comillas.

Hay tres métodos para corregir un programa. El primero consiste en escribir nuevamente la línea errónea. Al hacerlo, la línea nueva sustituye a la que había en la memoria con el mismo número.

El segundo es el "método del cursor de edición".

El tercero es el "método del cursor de copia".

Método del cursor de edición

Vamos a corregir el error de la línea 5.

Escriba lo siguiente: 

edit 5 [RETURN]

En la pantalla aparece la línea 5, por debajo de la 30, con el cursor situado sobre la c de clss.

Para suprimir la s que sobra, pulse la tecla de movimiento del cursor [→] hasta que éste quede sobre la última s de clss; pulse la tecla [CLR] y observe como desaparece la s.

A continuación pulse [RETURN] para introducir la versión corregida de la línea 5 en la memoria. Escriba 

list [RETURN]

y comprobará que la línea ha quedado corregida.

La orden AUTO, que describiremos más adelante en este manual, se puede combinar con este método para corregir un grupo de líneas sucesivas.

Método del cursor de copia

El cursor de copia es un segundo cursor, distinto del que puede ver en este momento en la pantalla, que aparece cuando se pulsa [MAYS] en combinación con alguna de las teclas de movimiento del cursor. De esta forma, el cursor de copia se separa del cursor ordinario y puede ser llevado a cualquier lugar de la pantalla.

Para corregir los errores de las líneas 10 y 30, pulse la tecla [MAYS] y, sin soltarla, pulse [↑] hasta llevar el cursor de copia al principio de la línea 10. Observe que el cursor principal no se ha movido, por lo que hay dos cursores en la pantalla. Ahora pulse varias veces [COPIA] hasta que el cursor de copia esté sobre el espacio que hay entre la t y la palabra llamas. Observe que el principio de la línea 10 ha sido copiado en la última línea de la pantalla y que el cursor principal se ha detenido en la misma columna que el de copia. Escriba la letra e, que aparecerá solamente en la línea inferior.

El cursor ordinario se ha movido, pero el de copia se ha quedado donde estaba. Pulse ahora [COPIA] hasta completar la copia de la línea 10. Pulse [RETURN] para transferir esta versión de la línea 10 a la memoria. El cursor de copia desaparece y el cursor ordinario queda por de bajo de la nueva línea 10.

Para corregir el otro error, mantenga pulsada la tecla [MAYS] y lleve el cursor de copia con la tecla [↑] hasta el principio de la línea 30. Pulse [COPIA] hasta que el cursor de copia quede sobre las comillas que siguen a la coma. Pulse la barra espaciadora una vez, con lo que se inserta un espacio en la línea nueva. Pulse [COPIA] y no la suelte hasta que haya terminado de copiar el resto de la línea 30; pulse entonces [RETURN].

Compruebe que el programa ha quedado correctamente almacenado en la memoria escribiendo: 

list [RETURN]

Nota: Para llevar el cursor (durante el proceso de edición) al principio o al final de una línea, pulse la tecla [←] o la [→] una vez manteniendo pulsada al mismo tiempo la tecla [CONTROL].

Reinicialice el ordenador con [CONTROL] [MAYS] [ESC].

IF

Las palabras clave IF (sí) y THEN (entonces) se combinan para hacer que el ordenador realice una determinada acción en función del resultado de una comprobación especificada. Por ejemplo, en la instrucción 

if 1+1=2 then print "correcto" [RETURN]

el ordenador comprueba si es cierto que 1+1=2 y obra en consecuencia.

La palabra clave ELSE (si no) da un segundo curso de acción para el caso de que la comprobación de como resultado "falso" (o sea, que la condición no se cumpla). Por ejemplo, 

if 1+1=0 then print "correcto" else print "falso" [RETURN]

Vamos a ampliar nuestro programa anterior con la instrucción IF ... THEN. Escriba lo siguiente: 

5 cls [RETURN]
10 input "como te llamas";a$ [RETURN]
20 input "cuantos años tienes";edad [RETURN]
30 if edad < 13 then 60 [RETURN]
40 if edad < 20 then 70 [RETURN]
50 if edad > 19 then 80 [RETURN]
60 print "Bueno,";a$;", todavia no eres un adolescente a los";edad; "años":end [RETURN]
70 print "Bueno, ";a$;", a tus";edad;"años eres un adolescente":end [RETURN]
80 print "Que le vamos a hacer, ";a$;", ya no eres un adolescente a tus";edad;"años" [RETURN]

(Observe que hemos introducido dos símbolos nuevos: <, que significa "menor que" y está junto a la tecla de la M, y >, que significa "mayor que" y está junto a la tecla de <.) Para comprobar que el programa ha quedado correctamente introducido en la memoria escriba 

list [RETURN]

y a continuación 

run [RETURN]

Responda a las preguntas que le haga el ordenador y vea qué ocurre.

En este ejemplo puede observar el efecto de la instrucción IF ... THEN. También hemos introducido una palabra clave nueva: END (fin); su efecto es concluir la ejecución del programa. Si no estuviera END en la línea 60, el programa continuaría en la línea 70. Por lo mismo, si no hubiéramos puesto END en la línea 70, el programa no terminaría en ella, sino que ejecutaría también la 80. El signo de dos puntos (:) que precede a la palabra END separa esta palabra de la instrucción anterior. Este signo se puede utilizar para separar instrucciones cuando interese poner varias en una misma línea de programa. También hemos incluido la línea 5, en la que borramos la pantalla. En lo sucesivo seguiremos haciéndolo, para obtener programas más "elegantes" y evitar confusiones.

Reinicialice la máquina pulsando las teclas [CONTROL] [MAYS] [ESC].

FOR ... NEXT

Estas palabras clave se utilizan cuando se desea que una parte del programa se repita cierto número de veces. Las instrucciones que deban repetirse son las que se incluyen dentro del bucle FOR ... NEXT (para ... siguiente).

Escriba lo siguiente: 

5 cls [RETURN]
10 for a=1 to 10 [RETURN]
20 print "operacion numero:";a [RETURN]
30 next a [RETURN]
run INTRO

Como puede ver, la acción de la línea 20 ha sido realizada 10 veces, tal como exige la instrucción FOR de la línea 10. Observe también cómo se ha ido incrementando de 1 en 1 la variable a.

La palabra clave STEP (paso) se puede incluir en la instrucción FOR ... NEXT para especificar la forma en que debe incrementarse o decrementarse la variable de control del bucle. Por ejemplo, modifique la línea 10 y ejecute el programa: 

10 for a=10 to 50 step 5 [RETURN]

El paso también puede ser negativo. Por ejemplo:

10 for a=100 to 0 step -10 [RETURN]
run [RETURN]

REM

REM es abreviatura de REMark (observación, comentario). Esta instrucción indica al ordenador que debe ignorar todo lo que haya después de ella en la línea de programa. Sirve, pues, para hacer anotaciones al programa; por ejemplo, el título, el significado de una variable, etc.: 

10 REM Fulminar los invasores [RETURN]
20 S=5:REM numero de supervivientes [RETURN]

El signo de comilla ' (que se obtiene de la tecla del 7 con [SHIFT] es a su vez abreviatura de :REM. Por ejemplo, 

10 'Fulminar los invasores [RETURN]
20 S=5 'numero de supervivientes [RETURN]

GOSUB

Si en un programa hay un grupo de instrucciones que deban ser ejecutadas varias veces, no es necesario escribirlas reiteradamente cada vez que el programa las necesite. Lo que se hace es ponerlas en una "subrutina", la cual puede ser invocada siempre que se desee mediante la instrucción GOSUB (ir a subrutina) seguida del número de la línea donde empieza la subrutina. El final de la subrutina se señala con la instrucción RETURN (retorno). Cuando el programa llega a RETURN, la ejecución salta a la instrucción siguiente al GOSUB que invocó la subrutina.

(Los dos programas siguientes no hacen más que escribir la letra de una canción popular en la pantalla, y por lo tanto no es necesario que se tome la molestia de introducirlos en el ordenador. Los hemos incluido aquí solamente para demostrar cómo se pueden utilizar las subrutinas para realizar tareas repetidas.)

En el siguiente programa: 

10 MODE 2 [RETURN]
20 PRINT "Dicen que no la quieres y la regalas" [RETURN]
30 PRINT "Peritas de Don Guindo y uvas tempranas" [RETURN]
40 PRINT "Al tribulete" [RETURN]
50 PRINT "Que no quiere bailar con usted" [RETURN]
60 PRINT "Dejala, dejala sola" [RETURN]
70 PRINT [RETURN]
80 PRINT "Es tu cara lo mismo que luna blanca" [RETURN]
90 PRINT "Y tus ojos luceros que la acompañan" [RETURN]
100 PRINT "Al tribulete" [RETURN]
110 PRINT "Que no quiere bailar con usted" [RETURN]
120 PRINT "Dejala, dejala sola" [RETURN]
130 PRINT [RETURN]
140 PRINT "Tengo yo comparado, niña, tu rostro" [RETURN]
150 PRINT "Con la luna de enero y el sol de agosto" [RETURN]
180 PRINT "Al tribulete" [RETURN]
190 PRINT "Que no quiere bailar con usted" [RETURN]
200 PRINT "Dejala, dejala sola" [RETURN]
210 PRINT [RETURN]
run [RETURN]

puede observar que hemos repetido varias instrucciones. Por ejemplo, la línea 40 (principio del estribillo) está repetida en la 100 y en la 180. Pongamos todo el estribillo en una subrutina, con [RETURN] al final; entonces podremos "llamarlo" con la instrucción GOSUB 180 cada vez que lo necesitemos. El programa queda de la siguiente forma: 

10 MODE 2 [RETURN]
20 PRINT "Dicen que no la quieres y la regalas" [RETURN]
30 PRINT "Peritas de Don Guindo y uvas tempranas" [RETURN]
40 GOSUB 180 [RETURN]
80 PRINT "Es tu cara lo mismo que luna blanca" [RETURN]
90 PRINT "Y tus ojos luceros que la acompañan" [RETURN]
100 GOSUB 180 [RETURN]
140 PRINT "Tengo yo comparado, niña, tu rostro" [RETURN]
150 PRINT "Con la luna de enero y el sol de agosto" [RETURN]
170 END [RETURN]
180 PRINT "Al tribulete" [RETURN]
190 PRINT "Que no quiere bailar con usted" [RETURN]
200 PRINT "Dejala, dejala sola" [RETURN]
210 PRINT [RETURN]
220 RETURN [RETURN]
run [RETURN]

El ahorro de trabajo es evidente. El correcto diseño de subrutinas es una faceta esencial de la informática. Con ellas se puede escribir programas "estructurados"; son la base para la adquisición de buenos hábitos de programación.

Cuando escriba subrutinas, tenga en cuenta que no está obligado a saltar siempre a su primera línea. Por ejemplo, si hay una rutina en las líneas 500 a 800, podría interesar llamarla con GOSUB 500, con GOSUB 640 o con GOSUB 790, según las funciones de la subrutina que se desee ejecutar.

Observe que en el programa anterior hemos incluido la instrucción END en la línea 170 para aislar la subrutina del resto del programa. De no haberlo hecho, el programa pasaría de la línea 160 a la 180.

Aritmética sencilla

El ordenador se puede utilizar como calculadora.

Para aprender cómo hacerlo, pruebe los siguientes ejemplos. En esta sección utilizamos el signo de interrogación ? como abreviatura de print. El ordenador escribe la respuesta en cuanto se pulsa [RETURN].

Suma

Escriba 

?3+3 [RETURN]
6

(No se teclea el signo = ).

Escriba: 

?8+4 [RETURN]
12

Resta

(no confunda el signo menos "-" con el de subrayado "_").

Escriba: 

?4-3 [RETURN]
1

Escriba: 

?8-4 [RETURN]
4

Multiplicación

(el signo de multiplicación es el asterisco *).

Escriba: 

?3*3 [RETURN]
9

Escriba: 

?8*4 [RETURN]
32

División

(el signo de dividir es la barra inclinada hacia la derecha, /).

Escriba: 

?3/3 [RETURN]
1

Escriba: 

?8/4 [RETURN]
2

División entera

(es la división en la que se ignora el resto; su signo es la barra inclinada hacia la izquierda \).

Escriba: 

?10\6 [RETURN]
1

Escriba: 

?20\3 [RETURN]
6

Módulo

(la operación MOD da el resto de la división entera).

Escriba: 

?10 MOD 4 [RETURN]
2

Escriba: 

?9 MOD 3 [RETURN]
0

Raíz cuadrada

Para hallar la raíz cuadrada de un número se utiliza la función sqr( ). El número del que se va a extraer la raíz (esto es, el radicando) se pone entre los paréntesis. Escriba: 

?sqr(16) [RETURN]
4

(esto significa √16).

Escriba: 

?sqr(100) [RETURN]
10

Potenciación

(en los ordenadores el signo de "elevar a una potencia" es la flecha hacia arriba, que en el AMSTRAD se obtiene de la tecla de [Pt] sin [MAYS]).

La potenciación es la operación de elevar un número a una potencia; es decir, multiplicarlo por sí mismo tantas veces como indica el exponente. Por ejemplo, 3 al cuadrado (3^2), 3 al cubo (3^3), 3 a la cuarta (3^4), etc.

Escriba (sustituya el carácter ^ por ↑): 

?3^3 [RETURN]
27

(esto significa 3^3).

Escriba (sustituya el carácter ^ por ↑): 

?8^4 [RETURN]
4096

(esto significa 8^4).

Raíz cúbica

Extraer la raíz cúbica de un número es lo mismo que elevarlo a la potencia 1/3. Así, para hallar la raíz cúbica de 27 (∛27) escriba (sustituya el carácter ^ por ↑):

?27^(1/3) [RETURN]
33

Para hallar la raíz cúbica de ∛125 escriba (sustituya el carácter ^ por ↑): 

?125^(1/3) [RETURN]
5

Operaciones combinadas (+, -, *, /)

El ordenador entiende correctamente las operaciones combinadas, pero es necesario saber con qué orden de prioridad las realiza.

La primera prioridad es para la multiplicación y la división; la segunda, para la suma y la resta. Este orden de prioridad es válido solamente para los cálculos en los que no intervienen más que estas operaciones.

Si la operación fuera: 

3+7–2*7/4

se podría pensar que el ordenador la realizaría de la forma: 

3+7-2 *7/4 
=8 *7/4
=56/4 
=14

Sin embargo, el proceso de cálculo es como sigue: 

3+7–2*7/4
=3+7-14/4
=3+7–3.5
= 10–3.5
=6.5

Compruébelo escribiendo 

?3+7-2*7/4 [RETURN]
6.5

Para alterar este orden se pueden incluir paréntesis según convenga. El ordenador realiza las operaciones internas a los paréntesis antes que las externas. Compruébelo escribiendo lo siguiente: 

?(3+7-2)* 7/4 [RETURN]
14

El orden completo de prioridad de las operaciones matemáticas es el siguiente:

SímboloOperación
↑Potenciación
MODMódulo
-Cambio de signo
* y /Multiplicación y división
\División entera
+ y -Suma y resta

Más exponentes

Cuando en los cálculos van a intervenir números muy grandes o muy pequeños, es conveniente a veces utilizar notación científica. La letra E (mayúscula o minúscula) indica que el número que está a su derecha es una potencia de 10.

Por ejemplo, 300 es lo mismo que 3 x 10^2. En notación científica escribiríamos 3E2. Análogamente, 0.03 es igual a 3x10^-2; en notación científica, 3E-2. Pruebe los siguientes ejemplos.

Puede escribir 

?30*30 [RETURN]
300

o bien

?3E1*1E1 [RETURN]
300 

?3000*1000 [RETURN] ... o bien ... ?3E3*1E3 [RETURN]
3000000
?3000*0.001 [RETURN] ... o bien ... ?3E3*1E-3 [RETURN]
3